Все для Sony Ericsson, патчи, эльфы, моддинг, прошивка
  
Логин: Пароль: Запомнить: Привет гость! Зарегистрируйся или авторизируйся для получения доп. возможностей!
Разделы
PDA версия сайта
TrackIDentify
Новости
Статьи
Файлы
Патчи
Патчи A2
Патчи db2020
Эльфы
Исходники эльфов
Wiki
Форум
Опросы
Обратная связь
Развернуть/Свернуть
 
Развернуть/Свернуть

Исходники патчей : Патчестроение : Патчи : Форум : Для Sony Ericsson патчи эльфы моддинг прошивка
/  Список форумов
   /  Патчи
      /  Патчестроение
   /  Исходники патчей
На печать 
Правила 
Страница 3 из 4: « 1 2 [3] 4 »

CleverUser


Опытный


Регистрация: 29.4.09
Сообщений: 214
Репутация: 163
Откуда: Киев




 
  #21 [12.03.11, 19:51] Re: Исходники патчей   

 
Это из-за экзешников в проэктах иаровских патчей. Залил архив без них

[ Редактировано CleverUser в 12.3.11 18:56 ]



Прикрепленный к сообщению файл:

sources.zip sources.zip (415.15 kb; 79 hits) Скачать файл


Спасибо сказали: E1kolyan, cires, agnalp, MAVER145

a6b6


Patcher


Регистрация: 15.5.10
Сообщений: 150
Репутация: 2580





 
  #22 [27.07.11, 18:51] Re: Исходники патчей   

 
Код:
Add left softkey Minim. for playing music in FileManager-W595_R3EF001
Adding to the Radio item WAKMAN-W595_R3EF001
Addition Background Pic and Brightness to Menu - Options-W595_R3EF001
Automatic recording of the voice at the beginning of a voice call-W595_R3EF001
Поддержка кодировки win-1251-W595_R3EF001
Allows you to adjust brightness from 10 to 100% W595 SW-R3EG004






[ Редактировано a7b7 в 28.7.11 20:23 ]



Прикрепленный к сообщению файл:

Allows_you_to_adjust_brightness_from_10_to_100_W595_SW-R3EG004.7z Allows_you_to_adjust_brightness_from_10_to_100_W595_SW-R3EG004.7z (0.71 kb; 21 hits) Скачать файл
Add_left_softkey_Minim._for_playing_music_in_FileManager.7z Add_left_softkey_Minim._for_playing_music_in_FileManager.7z (0.80 kb; 6 hits) Скачать файл
Adding_to_the_Radio_item_WAKMAN.7z Adding_to_the_Radio_item_WAKMAN.7z (0.79 kb; 8 hits) Скачать файл
Addition_Background_Pic_and_Brightness_to_Menu_-_Options.7z Addition_Background_Pic_and_Brightness_to_Menu_-_Options.7z (1.07 kb; 9 hits) Скачать файл
Automatic_recording_of_the_voice_at_the_beginning_of_a_voice_call.7z Automatic_recording_of_the_voice_at_the_beginning_of_a_voice_call.7z (0.95 kb; 7 hits) Скачать файл
Podderzhka_kodirovki_win-1251.7z Podderzhka_kodirovki_win-1251.7z (0.90 kb; 7 hits) Скачать файл


с510 ) w660i
'Фу' сказали: Se-MaG, Nook, D3mon, Vov4ик, Neodzen

E1kolyan


Developer


Регистрация: 8.7.07
Сообщений: 663
Репутация: 11808
Откуда: Челябинск




 
  #23 [13.05.12, 22:11] Re: Исходники патчей   

 
Код: 
;C510 SW-R1HA035
;Добавить сетку в видоискатель камеры
;Добавлено вкл/выкл нажатием клавиши 1 в камере
;(!) Хранение настроек патчей в реестре, v. 2
;(c) blacklizard
;(e) E1kolyan

include "%fasminc%\x.inc"
code16

org 0x14F7E90C
ldr r3, _key
bx r3

org 0x14F7EA16
nop
_key dw key+1

org 0x14FCF548
ldr r3, _add_grid
bx r3
_add_grid dw add_grid+1

org 0x15D84600
key:
cmp r5, 0x19
bne if_not
bl GetSetting
cmp r0, 0
beq if_off
mov r3, 0
b reg_set
if_off:
mov r3, 1
reg_set:
mov r2, 0
mov r1, 1
ldr r0, _value_name
bl 0x15D8402C ; void Registry_Write(char* name, int type, int size, void* data)
mov r1, 0
mov r0, r4
ldr r3, DispObject_InvalidateRect
blx r3
pop {r0-r7,pc}

if_not:
ldr r3, _return_key
bx r3

add_grid:
ldr r2, _line_num
mov r1, r5
mov r0, r6
ldr r3, TextID_Destroy
blx r3
bl GetSetting
cmp r0, 0
beq grid_off
bl AddGreed
grid_off:
ldr r3, _return_camera
bx r3

GetSetting:
push {r0,lr}
mov r3, sp
mov r2, 4
mov r0, 0
str r0, [sp]
ldr r0, _value_name
mov r1, 1
bl 0x15D840A0 ; void Registry_Read(char* name, int type, int size, void* data)
ldr r0, [sp]
pop {r3,pc}

AddGrid:
push {r4,lr}
mov r1, 0
ldr r0, _color_red
push {r0,r1}
mov r4, 0
mvn r4, r4
mov r3, 0xA0
movl r2, 0x141
mov r1, 0x50
mov r0, r4
bl _DrawRect
mov r1, 0
ldr r0, _color_red
push {r0,r1}
mov r3, 0xF1
mov r2, 0xD6
mov r0, 0x6B
mov r1, r4
bl _DrawRect
pop {r0-r4,pc}

_DrawRect:
push {r3}
ldr r3, DrawRect
mov r12, r3
pop {r3}
bx r12

align 4
_line_num dw 0x679
_return_camera dw 0x14FCF552+1
_return_key dw 0x14F7E912+1
_color_red dw 0xFFFF0000
_value_name dw value_name

TextID_Destroy dw 0x14182788+1
DispObject_InvalidateRect dw 0x140CA948+1
DrawRect dw 0x1445A7BC+1

value_name db "camera_grid",0





Sony Ericsson C905 SW-R1FA035
Sony Ericsson K810 SW-R8BF003
Sony Xperia™ S
ZTE Blade X3

E1kolyan


Developer


Регистрация: 8.7.07
Сообщений: 663
Репутация: 11808
Откуда: Челябинск




 
  #24 [18.05.12, 20:11] Re: Исходники патчей   

 
Еще немного...

Код: 
;C510 SW-R1HA035
;Добавить к часам в статус строке процент заряда батареи
;(c) E1kolyan
include "%fasminc%\x.inc"
code16

org 0x1430A1FA
bx r6

org 0x1430A2D0
dw patch+1

org 0x15D43BE0
patch:
ldr r6, empty_textid
mov r0, r7
bl get_textid
ldr r3, _return
bx r3

empty_textid dw 0x6FFFFFFF
_return dw 0x1430A1FC+1

get_textid:
push {r4,lr}
sub sp, sp, 0x44
add r1, sp, 0x10
mov r4, r0
mov r0, 0
bl _GetBatteryState
str r4, [sp]
ldr r0, space
str r0, [sp,4]
add r0, sp, 0x10
add r0, 0x20
ldrb r0, [r0]
bl _TextID_CreateIntegerID
str r0, [sp,8]
mov r2, 1
mov r1, 0
adr r0, percent
bl _TextID_Create
str r0, [sp,0xc]
mov r2, 4
mov r1, 5
mov r0, sp
bl _TextID_Create
add sp, sp, 0x44
pop {r4,pc}
nop

space dw 0x78000020
percent du "%",0

_GetBatteryState:
ldr r3, dw_1
bx r3
dw_1 dw 0x1016A564+1

_TextID_Create:
ldr r3, dw_2
bx r3
dw_2 dw 0x141818E4+1

_TextID_CreateIntegerID:
ldr r3, dw_3
bx r3
dw_3 dw 0x1401F5BC+1


Код: 
;C510 SW-R1FA035 Orange
;Возможность установить сообщение на приветствие
;Выбор и настройка текста в Параметры/Дисплей/Экран приветствия/Сообщение
;Время отображения сообщения - 5 сек.
;Колличество вводимых сиволов - 40
;(c) E1kolyan

include "%fasminc%\x.inc"
code16

org 0x158CABE4
cmp r0, 2
org 0x158CABE8
sub r0, r0, 4

org 0x141AB5EC
ldr r3, dw_1
bx r3
dw_1 dw patch_text+1

org 0x158CAECC
ldr r3, dw_2
bx r3
dw_2 dw patch_checked+1

org 0x158CAF9C
mov r1, 4
org 0x158CAFCC
bx r1
org 0x158CB034
dw patch_name+1

org 0x158CAC14
ldr r3, dw_4
bx r3
dw_4 dw patch_item_option+1

org 0x14FD38F0
ldr r3, dw_5
bx r3
dw_5 dw patch_show+1

org 0x15DD9BD0
patch_text:
bl startup_screen_mode__get
mov r5, r0
cmp r0, 4
beq set_text_mes
cmp r0, 2
ldr r3, return_patch_text_1
bx r3
set_text_mes:
movl r1, 0x364
ldr r3, return_patch_text_2
bx r3

patch_checked:
mov r1, 3
strb r1, [r0]
lsl r5, r1, 9
bl startup_screen_mode__get
cmp r0, 4
beq set_checked
ldr r3, return_patch_checked_1
bx r3
set_checked:
mov r0, sp
mov r1, 2
strb r1, [r0]
ldr r3, return_patch_checked_2
bx r3

patch_name:
ldr r1, item_name
mov r2, 5
ldr r0, [r4,0x18]
ldr r3, return_item_name
bx r3

patch_item_option:
cmp r0, 2
beq text_option
mov r0, r4
bl FreeBook
pop {r4,r5,pc}
text_option:
ldr r1, _setting_page
mov r0, r4
bl BookObj_GotoPage
pop {r4,r5,pc}

patch_show:
ldrb r0, [r4,r0]
cmp r0, 0
bne if_unk
mov r0, sp
ldrb r0, [r0]
cmp r0, 4
beq if_show
ldr r3, return_patch_show_1
bx r3
if_show:
bl show_message
ldr r3, return_patch_show_3
bx r3
if_unk:
ldr r3, return_patch_show_2
bx r3

setting:
push {r4,lr}
mov r4, r1
mov r0, r4
bl CreateStringInput
str r0, [r4,0x18]
cmp r0, 0
beq free
ldr r1, title_text
bl GUIObject_SetTitleText
mov r1, 1
ldr r0, [r4,0x18]
bl StringInput_SetMode
mov r1, 1
ldr r0, [r4,0x18]
bl StringInput_SetTextMinLengh
mov r1, 0x28
ldr r0, [r4,0x18]
bl StringInput_SetTextMaxLengh
bl get_buffer_text
mov r1, r0
ldr r0, [r4,0x18]
bl StringInput_SetStrinpText
mov r1, 5
ldr r0, [r4,0x18]
bl GUIObject_SetStyle
ldr r1, input_icon
ldr r0, [r4,0x18]
bl GUIInput_SetIcon
ldr r1, _input_ok
ldr r0, [r4,0x18]
bl StringInput_SetActionOK
ldr r1, _input_back
ldr r0, [r4,0x18]
bl StringInput_SetActionBack
ldr r0, [r4,0x18]
bl GUIObject_Show
free:
mov r0, 1
pop {r4,pc}

input_ok:
push {r4,lr}
mov r2, 0
mov r4, r0
ldr r0, _value_name
bl registry_write__apps_ui_standby_wchar
mov r0, 4
bl startup_screen_mode__set
mov r0, r4
bl FreeBook
pop {r4,pc}

input_back:
push {lr}
bl FreeBook
pop {pc}

get_buffer_text:
push {r4,r5,lr}
mov r1, 0
ldr r0, _mem_name
push {r0,r1}
mov r3, 5
mov r2, 1
mov r0, 0
mov r1, 0x60
mvn r0, r0
bl memalloc
mov r4, r0
mov r1, r4
ldr r0, _value_name
bl registry_read__apps_ui_standby_wchar
mov r0, r4
bl wstrlen
mov r2, r0
mov r1, 0
mov r0, r4
bl TextID_Create
mov r5, r0
add sp, sp, 8
cmp r4, 0
beq if_no_mem
mov r3, 0
ldr r2, _mem_name
mov r1, r4
mov r0, 0
bl memfree
if_no_mem:
mov r0, r5
pop {r4,r5,pc}

show_message:
push {r4,lr}
bl get_buffer_text
mov r4, r0
ldr r0, show_time
mov r1, 0
push {r0,r1}
mov r3, 1
ldr r0, empty_text
mov r2, 0
mov r1, r4
bl MessageBox
pop {r2-r4,pc}

startup_screen_mode__set:
ldr r3, _startup_screen_mode__set
bx r3

startup_screen_mode__get:
bx pc
align 4
code32
ldr pc, _startup_screen_mode__get
code16

registry_write__apps_ui_standby_wchar:
ldr r3, _registry_write__apps_ui_standby_wchar
bx r3

registry_read__apps_ui_standby_wchar:
ldr r3, _registry_read__apps_ui_standby_wchar
bx r3

BookObj_GotoPage:
ldr r3, _BookObj_GotoPage
bx r3

FreeBook:
ldr r3, _FreeBook
bx r3

CreateStringInput:
ldr r3, _CreateStringInput
bx r3

GUIObject_SetTitleText:
ldr r3, _GUIObject_SetTitleText
bx r3

StringInput_SetMode:
ldr r3, _StringInput_SetMode
bx r3

StringInput_SetTextMinLengh:
ldr r3, _StringInput_SetTextMinLengh
bx r3

StringInput_SetTextMaxLengh:
ldr r3, _StringInput_SetTextMaxLengh
bx r3

StringInput_SetStrinpText:
ldr r3, _StringInput_SetStrinpText
bx r3

GUIObject_SetStyle:
ldr r3, _GUIObject_SetStyle
bx r3

GUIInput_SetIcon:
ldr r3, _GUIInput_SetIcon
bx r3

StringInput_SetActionOK:
ldr r3, _StringInput_SetActionOK
bx r3

StringInput_SetActionBack:
ldr r3, _StringInput_SetActionBack
bx r3

GUIObject_Show:
ldr r3, _GUIObject_Show
bx r3

wstrlen:
ldr r3, _wstrlen
bx r3

TextID_Create:
ldr r3, _TextID_Create
bx r3

memalloc:
push {r3}
ldr r3, _memalloc
mov r12, r3
pop {r3}
bx r12

memfree:
push {r3}
ldr r3, _memfree
mov r12, r3
pop {r3}
bx r12

MessageBox:
push {r3}
ldr r3, _MessageBox
mov r12, r3
pop {r3}
bx r12

align 4
item_name dw _item_name 
_setting_page dw setting_page
_input_ok dw input_ok+1
_input_back dw input_back+1
title_text dw 0x290D ; Введите текст
input_icon dw 0x32E ; FR_INPUT_GUI_STRING_GENERIC_ICN
_value_name dw value_name
_mem_name dw mem_name
empty_text dw 0x6FFFFFFF
show_time dw 0x1388

_item_name:
dw 0xBFA ; Изображение
dw 0x6BF ; Видео
dw 0x364 ; Сообщение
dw 0xFA8 ; По умолчанию
dw 0x58 ; Нет

return_item_name dw 0x158CAFD0+1
return_patch_checked_1 dw 0x158CAED6+1
return_patch_checked_2 dw 0x158CAFA0+1
return_patch_text_1 dw 0x141AB5F4+1
return_patch_text_2 dw 0x141AB68C+1
return_patch_show_1 dw 0x14FD38FA+1
return_patch_show_2 dw 0x14FD399E+1
return_patch_show_3 dw 0x14FD3A20+1

_startup_screen_mode__set dw 0x158CB304+1
_startup_screen_mode__get dw 0x141AB6E4+1
_registry_write__apps_ui_standby_wchar dw 0x158CB3AC+1
_registry_read__apps_ui_standby_wchar dw 0x142DC264+1
_BookObj_GotoPage dw 0x1447C0FC+1
_FreeBook dw 0x14127DE4+1
_CreateStringInput dw 0x140620D8+1
_GUIObject_SetTitleText dw 0x1443A450+1
_StringInput_SetMode dw 0x142C9A44+1
_StringInput_SetTextMinLengh dw 0x144A3E00+1
_StringInput_SetTextMaxLengh dw 0x140621B4+1
_StringInput_SetStrinpText dw 0x1401CB88+1
_GUIObject_SetStyle dw 0x14128260+1
_GUIInput_SetIcon dw 0x1430D808+1
_StringInput_SetActionOK dw 0x142C98DC+1
_StringInput_SetActionBack dw 0x1408DA4C+1
_GUIObject_Show dw 0x144C59A0+1
_wstrlen dw 0x14176DC4+1
_TextID_Create dw 0x1417F6A4+1
_memalloc dw 0x4BA31378
_memfree dw 0x4BA313A0
_MessageBox dw 0x158C9E2C+1

setting_page_name db "UI_StartupScreen_TextOption_Page",0,0,0,0
value_name db "startup-text",0,0,0,0
mem_name db "mem_greeting",0,0,0,0

setting_page_stuct:
dw 0xF
dw setting+1
dw 0
dw 0
setting_page:
dw setting_page_name
dw 0
dw setting_page_stuct


Код: 
;C510 SW-R1HA035
;Отображение колличества контактов и номеров во второй строке заголовка
;(c) E1kolyan

include "%fasminc%\x.inc"
code16

org 0x14EA690A
ldr r3, dw_1
bx r3
nop
dw_1 dw set_title_1+1

org 0x14EA6638
ldr r3, dw_2
bx r3
dw_2 dw set_title_2+1

org 0x15D42110
set_title_1:
mov r1, r6
bl SetTitle
ldr r3, return_title_1
bx r3

set_title_2:
mov r1, r6
bl SetTitle
ldr r3, return_title_2
bx r3

SetTitle:
push {r4-r6,lr}
sub sp, sp, 0x40
ldr r5, print_format
mov r4, r1
cmp r0, 2
bne set_sim
mov r1, 0
mov r0, 3
bl AB_GETNBROFITEMS
mov r6, r0
mov r1, 0
mov r0, 0
bl AB_GETNBROFITEMS
push {r6}
mov r3, r0
mov r2, r5
ldr r5, textid_phone
ldr r6, iconid_phone
mov r1, 0x20
add r0, sp, 4
bl snwprintf
add sp, sp, 4
b set_title
set_sim:
ldr r6, iconid_sim
mov r1, 0
mov r0, 4
bl AB_GETNBROFITEMS
mov r3, r0
mov r2, r5
add r2, format_sim - format_phone
mov r1, 0x20
mov r0, sp
bl snwprintf
add r5, textid_sim - format_phone
mov r2, 0xB
mov r1, 0
mov r0, r5
bl TextID_Create
mov r5, r0
set_title:
mov r1, 5
mov r0, r4
bl GUIObject_SetTitleType
movl r2, 0xFF
mov r1, 0
mov r0, sp
bl TextID_Create
mov r1, r0
mov r0, r4
bl GUIObject_SetSecondRowTitleText
mov r1, r5
mov r0, r4
bl GUIObject_SetTitleText
mov r1, r6
mov r0, r4
bl GUIObject_SetTitleIcon
add sp, sp, 0x40
pop {r4-r6,pc}

AB_GETNBROFITEMS:
ldr r3, _AB_GETNBROFITEMS
bx r3

snwprintf:
push {r3}
ldr r3, _snwprintf
mov r12, r3
pop {r3}
bx r12

GUIObject_SetTitleText:
ldr r3, _GUIObject_SetTitleText
bx r3

GUIObject_SetTitleType:
ldr r3, _GUIObject_SetTitleType
bx r3

TextID_Create:
ldr r3, _TextID_Create
bx r3

GUIObject_SetSecondRowTitleText:
ldr r3, _GUIObject_SetSecondRowTitleText
bx r3

GUIObject_SetTitleIcon:
ldr r3, _GUIObject_SetTitleIcon
bx r3

align 4
return_title_1 dw 0x14EA691A+1
return_title_2 dw 0x14EA6648+1
print_format dw format_phone

textid_phone dw 0x347
iconid_phone dw 0x659
iconid_sim dw 0x679

_AB_GETNBROFITEMS dw 0x1431F9CC+1
_snwprintf dw 0x143EEBC4+1
_GUIObject_SetTitleText dw 0x1443F740+1
_GUIObject_SetTitleType dw 0x14093534+1
_TextID_Create dw 0x141818E4+1
_GUIObject_SetSecondRowTitleText dw 0x1443F3D0+1
_GUIObject_SetTitleIcon dw 0x141F29A8+1

format_phone du 4,"Контакты: %d(%d)",0
format_sim du 4,"Номера: %d",0
textid_sim du 4,"Память SIM",0


Код: 
;C510 SW-R1FA035 Orange
;Замена окошка "Использовать сейчас?" при приеме файла на свое
;Автозакрытие через 5 сек.
;Использование известных и неизвестных файлов
;v. 3
;(c) E1kolyan
include "%fasminc%\x.inc"
code16

org 0x150E1076
b 0x150E10CE

org 0x150E10E2
b 0x150E10EA

org 0x150E1110
ldr r5, dw_1
bx r5
dw_1 dw timer+1

org 0x150E1130
dw kill_timer_no+1

org 0x150E1138
dw kill_timer_yes+1

org 0x15DDAE00
timer:
ldr r0, [sp,0xC]
bl create_timer
movl r1, 0x1DE
ldr r5, return
bx r5

create_timer:
ldr r1, on_timer
push {lr}
mov r2, r0
ldr r0, time
bl Timer_Set
ldr r1, timer_env
mov r2, r0
mov r0, 0
bl set_envp
pop {pc}

_on_timer:
push {r1,lr}
mov r0, r1
bl FreeBook
pop {r3,pc}

kill_timer_no:
push {lr}
bl FreeBook
bl kill_timer
pop {pc}

kill_timer_yes:
push {lr}
bl DataDownload_SetAs
bl kill_timer
pop {pc}

kill_timer:
ldr r1, timer_env
push {r0,lr}
mov r0, 0
bl get_envp
mov r1, sp
strh r0, [r1]
mov r0, sp
ldrh r0, [r0]
cmp r0, 0
beq if_not_found
mov r0, sp
bl Timer_Kill
if_not_found:
pop {r3,pc}

Timer_Set:
ldr r3, _Timer_Set
bx r3

Timer_Kill:
ldr r3, _Timer_Kill
bx r3

set_envp:
ldr r3, _set_envp
bx r3

get_envp:
ldr r3, _get_envp
bx r3

FreeBook:
ldr r3, _FreeBook
bx r3

DataDownload_SetAs:
ldr r3, _DataDownload_SetAs
bx r3

align 4
on_timer dw _on_timer+1
time dw 0x1388
timer_env dw _timer_env
return dw 0x150E10C0+1

_Timer_Set dw 0x1449A40C+1
_Timer_Kill dw 0x141786C4+1
_set_envp dw 0x101D6CE8+1
_get_envp dw 0x101D6CD4+1
_FreeBook dw 0x14127DE4+1
_DataDownload_SetAs dw 0x157C20B4+1

_timer_env db "un3_env",0





Sony Ericsson C905 SW-R1FA035
Sony Ericsson K810 SW-R8BF003
Sony Xperia™ S
ZTE Blade X3
Спасибо сказали: Metaler, KnoonK, farid, Neodzen

E1kolyan


Developer


Регистрация: 8.7.07
Сообщений: 663
Репутация: 11808
Откуда: Челябинск




 
  #25 [13.08.12, 20:46] Re: Исходники патчей   

 
Спасибо IronMaster за совет)
Код: 
;C510 SW-R1HA035
;Замена окошка "Использовать сейчас?" при приеме файла на свое
;Автозакрытие через 5 сек.
;Использование известных и неизвестных файлов
;(c) E1kolyan
;(r) IronMaster
include "%fasminc%\x.inc"
code16

org 0x14CB75F4 ; mem_size
dw 0x658

org 0x15B6AE04 ; page_exit
dw kill_timer+1

org 0x15075ED8 ; if_unknow
b 0x15075FDE

org 0x15075FF2 ; desc_text
b 0x15075FFA

org 0x15076020 ; timer and icon
ldr r0, [sp,0xC]
bl create_timer
movl r1, 0x1DE
ldr r0, [r4,8]
bl 0x15076178 ; YesNoQuestion_SetIcon
ldr r0, [r4,8]
b 0x15075FD8

org 0x15075F88
create_timer:
ldr r2, _on_timer
push {r4,lr}
mov r4, r0
mov r1, 0
mov r0, 0
push {r0,r1}
ldr r1, time
ldr r0, mem
mov r3, r4
add r0, r4, r0
bl 0x15049974 ; Timer_ReSet
pop {r2-r4,pc}

on_timer:
push {r1,lr}
mov r0, r1
bl 0x150760D8 ; FreeBook
pop {r3,pc}

kill_timer:
ldr r0, mem
push {r4,lr}
mov r4, r1
add r0, r4, r0
beq if_killed
mov r2, 0
mov r1, 0
bl 0x1506E638 ; Timer_Kill
if_killed:
mov r1, r4
mov r0, 0
ldr r3, return_exit
blx r3
pop {r4,pc}

align 4
_on_timer dw on_timer+1
time dw 0x1388
mem dw 0x654
return_exit dw 0x1401D84C+1





Sony Ericsson C905 SW-R1FA035
Sony Ericsson K810 SW-R8BF003
Sony Xperia™ S
ZTE Blade X3
Спасибо сказали: Neodzen

Nook


Patcher


Регистрация: 16.4.10
Сообщений: 256
Репутация: 2578
Откуда: Харьков. Украина




 
  #26 [20.07.14, 18:45] Re: Исходники патчей   

 
в связи что форматирую винт может пригодится
там все что портировалось



Прикрепленный к сообщению файл:

ishodniki.zip ishodniki.zip (926.97 kb; 21 hits) Скачать файл


Iphone 5se

мебель в стиле лофт z-loft - интернет магазин мебели
Спасибо сказали: a6b6, iksrman

E1kolyan


Developer


Регистрация: 8.7.07
Сообщений: 663
Репутация: 11808
Откуда: Челябинск




 
  #27 [13.11.16, 17:39] Re: Исходники патчей   

 
Код:
;Добавить паузу при воспроизведение аудио через Диспетчер файлов
;(c) E1kolyan


new
Код:
;Добавить пункт "Вибрация" в меню "Звук клавиш"
;v. 1
;(r) IronMaster
;(c) E1kolyan


[ Редактировано E1kolyan в 16.11.16 18:21 ]



Прикрепленный к сообщению файл:

DBPause_C510_R1HA035.zip DBPause_C510_R1HA035.zip (0.90 kb; 8 hits) Скачать файл
KeyVibration_C905_R1FA035.zip KeyVibration_C905_R1FA035.zip (1.10 kb; 8 hits) Скачать файл



Sony Ericsson C905 SW-R1FA035
Sony Ericsson K810 SW-R8BF003
Sony Xperia™ S
ZTE Blade X3

iksrman


Пользователь


Регистрация: 25.10.09
Сообщений: 88
Репутация: 915
Откуда: Братск




 
  #28 [14.11.16, 05:14] Re: Исходники патчей   

 
E1kolyan, не прикрепил код либо файлы.



E1kolyan


Developer


Регистрация: 8.7.07
Сообщений: 663
Репутация: 11808
Откуда: Челябинск




 
  #29 [16.11.16, 16:23] Re: Исходники патчей   

 
iksrman пишет:
E1kolyan, не прикрепил код либо файлы.

Забыл блин :-)





Sony Ericsson C905 SW-R1FA035
Sony Ericsson K810 SW-R8BF003
Sony Xperia™ S
ZTE Blade X3
Спасибо сказали: iksrman

iksrman


Пользователь


Регистрация: 25.10.09
Сообщений: 88
Репутация: 915
Откуда: Братск




 
  #30 [18.11.16, 10:15] Re: Исходники патчей   

 
E1kolyan пишет:
iksrman пишет:
E1kolyan, не прикрепил код либо файлы.

Забыл блин :-)

Вот этот исходник можешь выложить? Не на IAR )
Патч:
;Добавить информацию об аудиозаписи в диспетчер файлов
; - Отображение обложки альбома
; - Отображение прогрессбара, ползунка и обводки
; - Выбор типа прогрессбара: обычный и закругленные концы
; - Отображение времени: полное, текущее, оставшееся
; - Отображение тэгов: исполнитель, альбом, назване, год, жанр
; - Отображение информации: битрейт, частота дискретизации, аудио выход
; - Отображение иконок: фон, рамка
; - Настройка активности, цвета и т.д.
; - Настройка координат и шрифта в реальном времени
; - Возможность использовать цвет на фон
; - Включение/выключение анимации появления окна
; - Возможность свернуть окно
; - Редактирование тэгов в Music Tagger
; - Возможность показать/скрыть статусбар
; - Возможность показать/скрыть софты
; - Автозакрытие окна
; - Атообновление настроек
; - Переход на заданное время
; - Пауза
; - Управление:
; Джойстик вверх/вниз - громкость
; Джойстик влево - воспроизвести сначала
; Удержание джойстик влево/вправо - перемотка
; # - Приглушить/восстановить звук
; * - Блокировка кнопок
;v. 5.1
;(c) E1kolyan


Страница 3 из 4: « 1 2 [3] 4 »



  • Поиск
  • Права
Вы не можете начинать темы.
Вы не можете редактировать свои сообщения.
Вы не можете создавать опросы.
Вы не можете вкладывать файлы в сообщения.
Вы не можете отвечать на сообщения.
Вы не можете удалять свои сообщения.
Вы не можете голосовать.

Главная Новости Статьи Файлы Патчи Форум Опросы PDA
- Генерация страницы: 0.63 секунд | 11 Запросов | HTML: 72.87 КБ -